Theorem nregmodel

Description: The Axiom of Regularity ax-reg is false in the permutation model defined from F . Since the other axioms of ZFC hold in all permutation models ( permaxext through permac8prim ), we can conclude that Regularity does not follow from those axioms, assuming ZFC is consistent. (If we could prove Regularity from the other axioms, we could prove it in the permutation model and thus obtain a contradiction with this theorem.) Since we also know that Regularity is consistent with the other axioms ( wfaxext through wfac8prim ), Regularity is neither provable nor disprovable from the other axioms; i.e., it is independent of them. (Contributed by Eric Schmidt, 16-Nov-2025)

	Ref	Expression
Hypotheses	nregmodel.1	|- F = ( ( _I |` ( _V \ { (/) , { (/) } } ) ) u. { <. (/) , { (/) } >. , <. { (/) } , (/) >. } )
	nregmodel.2	|- R = ( `' F o. _E )
Assertion	nregmodel	|- -. A. x ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) )

Proof

Step	Hyp	Ref	Expression
1		nregmodel.1	|- F = ( ( _I |` ( _V \ { (/) , { (/) } } ) ) u. { <. (/) , { (/) } >. , <. { (/) } , (/) >. } )
2		nregmodel.2	|- R = ( `' F o. _E )
3		0ex	|- (/) e. _V
4	3	snid	|- (/) e. { (/) }
5		eleq1	|- ( y = (/) -> ( y e. { (/) } <-> (/) e. { (/) } ) )
6	3 5 4	ceqsexv2d	|- E. y y e. { (/) }
7		breq2	|- ( x = (/) -> ( y R x <-> y R (/) ) )
8	1 2	nregmodellem	|- ( y R (/) <-> y e. { (/) } )
9	7 8	bitrdi	|- ( x = (/) -> ( y R x <-> y e. { (/) } ) )
10	9	exbidv	|- ( x = (/) -> ( E. y y R x <-> E. y y e. { (/) } ) )
11		breq2	|- ( x = (/) -> ( z R x <-> z R (/) ) )
12	1 2	nregmodellem	|- ( z R (/) <-> z e. { (/) } )
13	11 12	bitrdi	|- ( x = (/) -> ( z R x <-> z e. { (/) } ) )
14	13	notbid	|- ( x = (/) -> ( -. z R x <-> -. z e. { (/) } ) )
15	14	imbi2d	|- ( x = (/) -> ( ( z R y -> -. z R x ) <-> ( z R y -> -. z e. { (/) } ) ) )
16	15	albidv	|- ( x = (/) -> ( A. z ( z R y -> -. z R x ) <-> A. z ( z R y -> -. z e. { (/) } ) ) )
17	9 16	anbi12d	|- ( x = (/) -> ( ( y R x /\ A. z ( z R y -> -. z R x ) ) <-> ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) ) )
18	17	exbidv	|- ( x = (/) -> ( E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) <-> E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) ) )
19	10 18	imbi12d	|- ( x = (/) -> ( ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) ) <-> ( E. y y e. { (/) } -> E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) ) ) )
20	3 19	spcv	|- ( A. x ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) ) -> ( E. y y e. { (/) } -> E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) ) )
21	6 20	mpi	|- ( A. x ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) ) -> E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) )
22		df-ral	|- ( A. z e. { (/) } -. z e. { (/) } <-> A. z ( z e. { (/) } -> -. z e. { (/) } ) )
23		breq2	|- ( y = (/) -> ( z R y <-> z R (/) ) )
24	23 12	bitrdi	|- ( y = (/) -> ( z R y <-> z e. { (/) } ) )
25	24	imbi1d	|- ( y = (/) -> ( ( z R y -> -. z e. { (/) } ) <-> ( z e. { (/) } -> -. z e. { (/) } ) ) )
26	25	albidv	|- ( y = (/) -> ( A. z ( z R y -> -. z e. { (/) } ) <-> A. z ( z e. { (/) } -> -. z e. { (/) } ) ) )
27	3 26	rexsn	|- ( E. y e. { (/) } A. z ( z R y -> -. z e. { (/) } ) <-> A. z ( z e. { (/) } -> -. z e. { (/) } ) )
28		df-rex	|- ( E. y e. { (/) } A. z ( z R y -> -. z e. { (/) } ) <-> E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) )
29	22 27 28	3bitr2ri	|- ( E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) <-> A. z e. { (/) } -. z e. { (/) } )
30		eleq1	|- ( z = (/) -> ( z e. { (/) } <-> (/) e. { (/) } ) )
31	30	notbid	|- ( z = (/) -> ( -. z e. { (/) } <-> -. (/) e. { (/) } ) )
32	3 31	ralsn	|- ( A. z e. { (/) } -. z e. { (/) } <-> -. (/) e. { (/) } )
33	29 32	bitri	|- ( E. y ( y e. { (/) } /\ A. z ( z R y -> -. z e. { (/) } ) ) <-> -. (/) e. { (/) } )
34	21 33	sylib	|- ( A. x ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) ) -> -. (/) e. { (/) } )
35	4 34	mt2	|- -. A. x ( E. y y R x -> E. y ( y R x /\ A. z ( z R y -> -. z R x ) ) )